Konwerter DMX -> PWM LED RGB

Code  - [expand]
Program pre AT89C2051:

 
$MOD51

$TITLE(E-MI - DMX to RGB PWM converter for LED driver V 3.0)

$NOPAGING

$DEBUG

 
; I/O pinout =====================================================================

 
; CPU Atmel AT89C1051, AT89C2051, AT89C4051

; P1.0..7 - DMX Start Address 0..255

; P1.0 - DMX serial data input

; P1.1 - Chanel1 PWM output - RED

; P1.2 - Chanel2 PWM output - GREEN

; P1.3 - Chanel3 PWM output - BLUE

; P1.4 - Nc

; P1.5 - Nc

; P1.7 - DMX Error led

 
 
; Variables Description ==========================================================

 
Rcom DATA 030h ; DMX Chanel1 - Red

Gcom DATA 031h ; DMX Chanel2 - Green

Bcom DATA 032h ; DMX Chanel3 - Blue

 
TOutLo DATA 03Ah ; DMX Error TimeOut L byte

TOutHi DATA 03Bh ; DMX Error TimeOut H byte

 
Slot DATA 03Dh ; Now arriving DMX slot

SlotNo DATA 03Eh ; Received slots (0..2)

Addr DATA 03Fh ; DMX start adderss - DIP switch

Break BIT 000h ; DMX Break OK, waiting for StartCode=0

 
 
; Interrupt vectors ==============================================================

 
ORG 0000h ; I/O initialisation after reset

AJMP INIT

NOP

 
ORG 000Bh ; PWM trigger interruption

AJMP PWM

NOP

 
; DMX512A Serial Communication ===================================================

ORG 0023h

PUSH ACC

PUSH PSW

CLR RI

JB RB8,OkSlot ; Data test

JB P3.0,DMXErr ; Break test

MOV A,SBUF

JNZ DMXErr

JB P3.0,DMXErr

MOV Slot,#0 ; Break OK

MOV SlotNo,#0 ; Start receiving DMX

SETB Break ; Break detected - wait for DMX StartCode

POP PSW

POP ACC

RETI

 
OkSlot: JNB Break,DSlot ; If not waiting for startcode after break

MOV A,SBUF

JNZ DMXErr ; Check DMX StartCode

CLR Break ; DMX StartCode ok

MOV TOutHi,#255 ; Reset DMX Error timeout

SETB P3.7 ; DMX Error LED -> Off

MOV A,P1 ; Read DMX Start Address from DIP Switch

CPL A

MOV Addr,A ; Save DMX Start Address

POP PSW

POP ACC

RETI

 
DMXErr: MOV SlotNo,#3 ; If is any DMX problem

CLR P3.7 ; DMX Error LED -> On

POP PSW

POP ACC

RETI

 
DSlot: MOV A,SlotNo ; If is correct DMX Data Slot

CJNE A,#3,TstNxt ; If is any datata slot for receiving

POP PSW

POP ACC

RETI

 
TstNxt: JNZ RecNxt

MOV A,Slot

CJNE A,Addr,NextS

 
RecNxt: MOV A,SlotNo ; Receive DMX Data Slot

ADD A,#030h

MOV R0,A

MOV @R0,SBUF

INC SlotNo

POP PSW

POP ACC

RETI

 
NextS: INC Slot ; Next slot

POP PSW

POP ACC

RETI

NOP

; End of DMX512A Serial Communication ============================================

 
 
; PWM trigger interruption - T0 ==================================================

PWM: MOV TH0,#255 ; Time set for T0 <<<<<<<<<<<<<<<<<<<<<<<<<<<

MOV TL0,#200

PUSH ACC ; Backup registers

PUSH PSW ;

 
INC R1 ; Triangular comparation counter for RED PWM

MOV A,Rcom ; Comparator Red

CJNE A,#0FFh,RNoFul

CLR P3.1

AJMP RFull

RNoFul: SETB C

SUBB A,R1

MOV P3.1,C

RFull:

INC R2 ; Triangular comparation counter for GREEN PWM

MOV A,Gcom ; Comparator Green

CJNE A,#0FFh,GNoFul

CLR P3.2

AJMP GFull

GNoFul: SETB C

SUBB A,R2

MOV P3.2,C

GFull:

INC R3 ; Triangular comparation counter for BLUE PWM

MOV A,Bcom ; Comparator Blue

CJNE A,#0FFh,BNoFul

CLR P3.3

AJMP BFull

BNoFul: SETB C

SUBB A,R3

MOV P3.3,C

BFull:

POP PSW ; Restore registers

POP ACC

RETI ; Returm from PWM interruption routine

NOP

; End Of PWM =====================================================================

 
 
; CPU Device Initialisation ======================================================

 
ORG 0100h ; Inicializacia CPU po resete

INIT: MOV P1,#0FFh ; [0]..[7] DIP Switch Adress

MOV P3,#0FFh ; [0]=DMX RxD [1]=Red OUT [2]=Green OUT [3]=Blue OUT [7]=Error LED

 
MOV SP,#50h ; Set stack pointer

 
MOV SlotNo,#3 ; Set waiting for DMX512 Break

MOV PCON,#00000000b ; Serial speed = 16MHz/64=250kb (DMX512A 1998 USITT)

MOV SCON,#10011000b ; Serial channel in mode "2" - 9bit UART - receiving

 
MOV TMOD,#00010001b ; T0, T1 mode (Fosc/12)/THn:TLn

MOV TCON,#00010000b ; Enable timer T0

 
MOV IE,#10010010b ; Enable interruption from Serial input and Timer0 TF0

MOV IP,#00010000b ; Prefer interruption from serial link

 
MOV Rcom,#0 ; Set Red value after reset

MOV Gcom,#0 ; Set Green value after reset

MOV Bcom,#0 ; Set Blue value after reset

 
MOV R1,#0 ; Init. triangular comparator counter for RED PWM - shift 0°

MOV R2,#84 ; Init. triangular comparator counter for Green PWM - shift 120°

MOV R3,#170 ; Init. triangular comparator counter for Blue PWM - shift 240°

 
; Main Loop ======================================================================

 
Loop: NOP

DJNZ TOutLo,Loop

DJNZ TOutHi,Loop ; DMX TimeOut 16bit counter ~1s

CLR P3.7 ; LED DMX Error -> On

MOV Rcom,#0 ; If is DMX Error - mute all PWM outputs

MOV Gcom,#0

MOV Bcom,#0

AJMP Loop

 
; End of Main Loop ===============================================================

 
END; Program End ====================================================================