Wyświetlacz biegów, zegarek, licznik przejechanych km do motocykla

Code Basic4GL - [expand]
 
$regfile = "m8def.dat"
$crystal = 8000000
 
'$swstack = 64
'$hwstack = 64
'$framesize = 32
 
Config Lcd = 16 * 2
Config Lcdbus = 4
Config Lcdpin = Pin , Db4 = Portd.4 , Db5 = Portd.0 , Db6 = Portd.3 , Db7 = Portd.1 , E = Portd.6 , Rs = Portd.5
 
Enable Interrupts
On Int0 Pomiar
Config Int0 = Falling
Enable Int0
 
 
Config Timer0 = Timer , Prescale = 256
On Timer0 Obsluga_lcd                                       '
Load Timer0 , 250
Enable Timer0
Stop Timer0
 
 
Config Clock = Soft
Time$ = "18:56:00"
 
 
 Config Portb.2 = Input                                     'BIEG+
 Config Portb.3 = Input                                     'BIEG-
 Config Portb.4 = Input                                     'luz
 Config Portd.2 = Input                                     'int0  pomiar dystansu
 Config Portc.2 = Input                                     'minuta
 Config Portc.4 = Output                                    'podświetlenie
 Config Portc.3 = Input                                     'migacze
 Config Portb.5 = Input                                     'set 1(km/ na dystans)
 Config Portc.5 = Input                                     'set2 (zerowanie dystansu)
 
 
Deflcdchar 0 , 32 , 32 , 32 , 1 , 3 , 7 , 15 , 31           'znak kierunkowskazu
Deflcdchar 1 , 31 , 15 , 7 , 3 , 1 , 32 , 32 , 32          
Deflcdchar 2 , 31 , 31 , 32 , 32 , 32 , 32 , 32 , 32       
Deflcdchar 3 , 17 , 17 , 32 , 32 , 32 , 32 , 32 , 32        
Deflcdchar 4 , 32 , 32 , 32 , 32 , 32 , 32 , 17 , 17       
Deflcdchar 5 , 32 , 32 , 32 , 32 , 32 , 32 , 31 , 31       
Deflcdchar 6 , 32 , 32 , 32 , 16 , 24 , 28 , 30 , 31      
Deflcdchar 7 , 31 , 30 , 28 , 24 , 16 , 32 , 32 , 32       
 
Dim Minuta As Byte
Dim Godzina As Byte
Dim Dystans As Single
Dim Obrotow_kola As Long
Dim Bieg As Byte
Dim Przebieg As String * 10
Dim Godzina_str As String * 2
Dim Minuta_str As String * 2
Dim Czas As String * 8
Dim Czas_godz As String * 2
Dim Czas_min As String * 2
Dim Powitanie As Bit
Dim Zegarek As String * 5
Dim Sekunda_str As String * 2
Dim Sekunda As Byte
Dim Kontrolna As Bit
Dim Cwierc_sek As Byte
Dim Tryb As Byte
Dim Impulsy_predkosc As Byte
Dim Sek_akt As String * 2
Dim Sek_akt_int As Byte
Dim Sek_test As Byte
Dim Predkosc As Byte
Dim Tryb_set As Bit
Dim Klik As Bit
Dim Mruganie As Bit
Dim Sek As Byte
Dim Odswierzanie As Byte
Dim Klik_bieg As Bit
Dim Setczas As String * 8
 
Klik_bieg = 0
Sek_test = 0
Dystans = 0
Obrotow_kola = 0
Przebieg = "0.0"
Cwierc_sek = 0
Tryb = 1
Tryb_set = 0
'Powitanie = 0
Sek_test = 00
Sek_akt_int = 00
Klik = 0
 
Cls
Cursor Off
Display Off
Portc.4 = 1
Do                                                          'Główna pętla programu
 
 
If Pinc.0 = 0 Then
 Waitms 25
If Pinc.0 = 0 Then
 
  If Powitanie = 0 Then
    Powitanie = 1
    Portc.4 = 0                                             'powitanie
    Display On
    Cls
    Locate 1 , 1
    Lcd " Honda"
    Locate 2 , 1
    Lcd " CB 500 "
    Wait 3
    Start Timer0
 
    Cls
  End If
 
 
'zlicznie  biegów
 
  If Pinb.2 = 0 And Bieg < 6 And Bieg > 0 And Klik_bieg = 0 Then
 
 
     Incr Bieg
     Klik_bieg = 1
 
 
  End If
 
  If Pinb.3 = 0 And Bieg > 1 And Klik_bieg = 0 Then
 
 
     Decr Bieg
     Klik_bieg = 1
 
 
  End If
 
  If Pinb.3 = 0 And Bieg = 0 And Klik_bieg = 0 Then         'zmiana biegu z luzu ( czyli 0 ) na 1 bieg
 
     Bieg = 1
     Klik_bieg = 1
 
 
  End If
 
 
  If Pinb.2 = 0 And Bieg = 0 And Klik_bieg = 0 Then         'zmiana biegu z luzu ( czyli 0 ) na 2 bieg
 
     Bieg = 2
     Klik_bieg = 1
 
 
  End If
 
 
  If Pinb.4 = 0 Then                                        'luz
 
     Bieg = 0
 
 
  End If
 
   If Pinb.3 = 1 And Pinb.2 = 1 Then
 
     Klik_bieg = 0
 
   End If
 
 
'obsluga przyciskow
 
 
  If Pinb.5 = 0 And Pinc.5 = 1 And Tryb <> 3 And Klik = 0 Then       'zmiana trybu wyświetlania
  Waitms 25
  If Pinb.5 = 0 And Pinc.5 = 1 And Tryb <> 3 And Klik = 0 Then
     Klik = 1
 
    Incr Tryb
 
    If Tryb = 3 Then
       Tryb = 1
    End If
 
  End If
  End If
 
  If Pinc.5 = 0 And Pinb.5 = 1 And Tryb <> 3 And Klik = 0 Then                    'zerowanie przebiegu
   Waitms 25
  If Pinc.5 = 0 And Pinb.5 = 1 And Tryb <> 3 And Klik = 0 Then
    Klik = 1
 
    Stop Timer0
    Locate 1 , 1
    Lcd "Czy na  "
    Locate 2 , 1
    Lcd "pewno ?"
    Wait 2
 
      If Pinc.5 = 0 And Pinb.5 = 1 And Tryb <> 3 Then
        Waitms 25
      If Pinc.5 = 0 And Pinb.5 = 1 And Tryb <> 3 Then
 
         Obrotow_kola = 0
         Dystans = 0
        Przebieg = "0.0"
        End If
        End If
        Start Timer0
 
     End If
     End If
 
  If Pinc.5 = 0 And Pinb.5 = 0 And Klik = 0 Then                     ' wejście / wyjście z trybu ustawiania czasu
   Waitms 25
  If Pinc.5 = 0 And Pinb.5 = 0 And Klik = 0 Then
    Klik = 1
    Toggle Tryb_set
 
    If Tryb_set = 1 Then
    Tryb = 3
    Setczas = Time$
    End If
 
    If Tryb_set = 0 Then
   Time$ = Setczas 
    Tryb = 1
 
    End If
 
  End If
  End If
 
  If Pinc.5 = 0 And Pinb.5 = 1 And Tryb = 3 Then               'ustawienie minuty
 Waitms 500
If Pinc.5 = 0 And Pinb.5 = 1 And Tryb = 3 Then
 
 
 
     Minuta_str = Mid(setczas , 4 , 2)
     Minuta = Val(minuta_str)
 
     Incr Minuta
       If Minuta = 60 Then
         Minuta = 0
       End If
 
     Minuta_str = Str(minuta)
     Minuta_str = Format(minuta_str , "00")
     Mid(setczas , 4 , 2) = Minuta_str
    Time$ = Setczas 
 
End If
End If
 
If Pinc.5 = 1 And Pinb.5 = 0 And Tryb = 3 Then                  'ustawienie godziny
 Waitms 500
If Pinc.5 = 1 And Pinb.5 = 0 And Tryb = 3 Then
 
 
     Godzina_str = Mid(setczas , 1 , 2)
     Godzina = Val(godzina_str)
 
 
       Incr Godzina
        If Godzina = 24 Then
         Godzina = 0
 
        End If
 
     Godzina_str = Str(godzina)
     Godzina_str = Format(godzina_str , "00")
 
     Mid(setczas , 1 , 2) = Godzina_str
 
 
 
 
End If
End If
 
If Pinc.5 = 1 And Pinb.5 = 1 Then
Waitms 25
If Pinc.5 = 1 And Pinb.5 = 1 Then
Klik = 0
End If
End If
 
End If
End If
 
 
 
If Pinc.0 = 1 Then
 Waitms 25
If Pinc.0 = 1 Then
  Portc.4 = 1
  Powitanie = 0
  Stop Timer0
  Display Off
 
 
End If
End If
'kalibracja czasu o 3 sekundy na dobę
 
 
     Godzina_str = Mid(time$ , 1 , 2)
     Godzina = Val(godzina_str)
     Minuta_str = Mid(time$ , 4 , 2)
     Minuta = Val(minuta_str)
     Sekunda_str = Mid(time$ , 7 , 2)
     Sekunda = Val(sekunda_str)
 
     If Godzina = 0 And Minuta = 0 And Sekunda = 0 And Kontrolna = 0 Then
 
      Time$ = "00:00:03"
      Kontrolna = 1
     End If
     If Godzina = 0 And Minuta = 0 And Sekunda = 4 Then
      Kontrolna = 0
     End If
 
 
     Czas = Time$
 
     Godzina_str = Mid(czas , 1 , 2)
     Godzina = Val(godzina_str)
 
 
     Minuta_str = Mid(time$ , 4 , 2)
     Minuta = Val(minuta_str)
 
      If Godzina > 23 Or Minuta > 59 Then
 
       Time$ = "00:00"
 
     End If
 
 
 
 
 
Loop                                                        ' Koniec głównej pętli
 
End
 
 
 
Pomiar:
 Incr Impulsy_predkosc
 Incr Obrotow_kola                                          'pomiar przejechanego dystansu, OBWÓD KOŁA 1.9m
 Dystans = Obrotow_kola * 0.0019
 Przebieg = Fusing(dystans , "#.&")
 
 
Return
 
Obsluga_lcd:
Load Timer0 , 250
 
      Czas = Time$
      Sek_akt = Mid(czas , 7 , 2)                           'obliczanie prędkości
      Sek_akt_int = Val(sek_akt)
 
    If Sek_test <> Sek_akt_int Then                         'Operacja Co Sekunda
 
     Predkosc = Impulsy_predkosc * 6.84                     '1.9m/s = 6.84km/s
     Impulsy_predkosc = 0
     Sek_test = Sek_akt_int
     Toggle Mruganie
    End If
 
 
Incr Odswierzanie
If Odswierzanie = 20 Then
 Odswierzanie = 0
 
    Zegarek = Time$
 
  Czas_godz = Mid(zegarek , 1 , 2)
  Czas_min = Mid(zegarek , 4 , 2)
  If Mruganie = 1 And Tryb <> 3 And Pinc.3 = 1 Then
 
   Locate 1 , 4
      Lcd Czas_godz ; ":" ; Czas_min
  End If
 
  If Mruganie = 0 And Tryb <> 3 And Pinc.3 = 1 Then
    Locate 1 , 4
      Lcd Czas_godz ; " " ; Czas_min
  End If
 
 
 
 
 If Pinc.3 = 1 Then
 
 
    If Tryb = 1 Then
                                                          'wyświetlenie biegu i zegarka
      If Bieg > 0 Then                                      '             prędkość
      Locate 1 , 1
      Lcd " " ; Bieg ; " ";
      End If
 
      If Bieg = 0 Then
      Locate 1 , 1
      Lcd " L "
      End If
 
 
     Locate 2 , 1
     Lcd Predkosc ; " km/h  ";
 
 
   End If
 
   If Tryb = 2 Then                                         'wyświetlenie bieg zegarek
                                                             '                dystans
     If Bieg > 0 Then
     Locate 1 , 1
     Lcd " " ; Bieg ; " ";
     End If
 
     If Bieg = 0 Then
     Locate 1 , 1
     Lcd " L " ;
     End If
 
     Locate 2 , 1
     Lcd Przebieg ; " km  "
   End If
 
   If Tryb = 3 Then                                         'ustawianie zegarka
 
 
    Locate 1 , 1
    Lcd Zegarek ; "   ";
 
 
    Locate 2 , 1
    Lcd "Set time";
   End If
 End If
 
 
 
 
If Pinc.3 = 0 Then
 
 
Locate 1 , 1
Lcd " " ; Chr(0) ; Chr(5) ; "  " ; Chr(5) ; Chr(6) ; " ";   'wyświetlenie strzałek
Locate 2 , 1
Lcd " " ; Chr(1) ; Chr(2) ; "  " ; ; Chr(2) ; Chr(7) ; " ";
 
End If
End If
 Return