Jak stworzyć kalkulator w Pascalu do dodawania dużych liczb?

program dodaj_natur;
{ Testujacy dzialanie funkcji, operujacej na duzych }
{ liczbach (pamietanych w zmiennych typu String).   }


uses
  Crt;

type
  TLiczba = String;

function Dodaj (A, B: TLiczba) : TLiczba;
{ Funkcja dodaje dwie duze liczby. }
var
  C : String;
  Przeniesienie, I, Liczba : Byte;
begin
  C := '';
  while Length(B) < Length(A) do B := '0' + B;
  while Length(A) < Length(B) do A := '0' + A;

  Przeniesienie := 0;
  for I := Length (A) downto 1 do
  begin
    Liczba := Ord(A[I])+Ord(B[I])-2*Ord('0') + Przeniesienie;
    Przeniesienie := Liczba div 10;
    Liczba := Liczba mod 10;
    C := Chr(Liczba+Ord('0')) + C;
  end;

  if (Przeniesienie > 0) then
    if Length(C)=255 then
      RunError(201)
    else
      C := Chr(Przeniesienie+Ord('0')) + C;
  Dodaj := C;
end; {--------------------------- Dodaj }

var
  Liczba1, Liczba2 : String;

begin
  writeln;
  repeat
    write ('Podaj pierwsza liczbe (Enter aby zakonczyc): '); readln (Liczba1);
    if (Liczba1<>'') then
    begin
      write ('Podaj druga liczbe: '); readln (Liczba2);
      writeln (Liczba1+'+'+Liczba2+'='+Dodaj (Liczba1, Liczba2));
    end;
  until (Liczba1<>'');
end.

 a, b: extended