Jak podłączyć wyświetlacz LCD SSC2M16ULGY-03? Problemy z uruchomieniem

LCD_INIT: 
  MOV A,#0FH			; inicjacja wyswietlacza LCD 
  LCALL CZEKAJ			;opoznienie 15 ms czas w akumulatorze
  CLR RW			;RW==0 zapis do LCD
  CLR RS			;RS==0 zapisujemy komendy do wyswietlacza LCD
  MOV R0,#3			;licznik petli
  PETLA: SETB E
  ANL  LCD,#09CH		;linie (D7-D4) 0011 Function Set
  CLR E				;opadajace zbocze zapisuje dana do LCD
  MOV A,#6
  LCALL CZEKAJ                    ;opoznienie 6 ms
  DJNZ R0,PETLA		       ;petla wykona sie 3 razy
  SETB E
  ANL LCD,#094H			;interfejs 4-bitowy (D7-D4) 0010
  CLR E
  MOV A,#01H			
  LCALL CZEKAJ			;opoznienie 1ms
  MOV A,#28H			;function set (4-bitowa,2 wiersze,5*7 znak)
  LCALL ZAPISZ_KOMENDE_LCD
  MOV A,#08H			;wyswietlacz OFF
  LCALL ZAPISZ_KOMENDE_LCD
  MOV A,#0CH			;wlaczenie wyswietlacza
  LCALL ZAPISZ_KOMENDE_LCD	
  MOV A,#06H			;po wpisaniu znaku inkrementacja kursora, przesow kursora w prawo
  LCALL ZAPISZ_KOMENDE_LCD
  LCALL MOJE_ZNAKI_LCD		;skok do procedury dodawania wlasnych znakow do LCD
RET

CZEKAJ:
  MOV R3,A			;procedura opozniajaca o czas zadany w akumlatorze w ms 
  L1: MOV R2,#10
  L2: MOV R1,#45
  L3:DJNZ R1,L3
  DJNZ R2,L2			; 940 cykle to jest okolo 1 ms dokladnie 1024us
  DJNZ R3,L1			;[(45*2)*10+10*3)]*R1+R1*3+1
RET

ZAPISZ_KOMENDE_LCD:  
  CLR RS   		;zerujemy RS bo zapisujemy komende do LCD procedura zapisu komendy z akumlatora do LCD
  LCALL ZAPISZ_DO_LCD
RET

LICZBA_NA_LCD:		;liczba jest w akumulatorze 
  PUSH ACC		;akumlator na stos
  SWAP A		;zamien polowkami akumulator
  LCALL BCD_TO_ASCI	;zmien dolna polowe akumlatora BCD na ascii
  LCALL ZAPISZ_ZNAK_DO_LCD
  POP ACC		;zdejmij akumlator ze stosu
  LCALL BCD_TO_ASCI
  LCALL ZAPISZ_ZNAK_DO_LCD
RET

BCD_TO_ASCI:			;zamiana liczby BCD na ASCII
ANL A,#0FH			
ADD A,#030H
RET

ZAPISZ_DO_LCD: 
  PUSH ACC		;procedura zapisu danej do wyswietlacza (dana w akumulatorze) 
  CLR RW		;zerujemy RW bo zapisujemy do LCD
  SETB E		;stan wysoki na lini E
  ANL A,#0F0H		;empty low
  CLR C			
  RRC A			;przesun akumlator w prawo
  ANL LCD,#087H 	;wyzeruj bity D7-D4 w porcie LCD
  ORL LCD,A		;odwzorowuje na liniach D7-D4 starsze 4 bity liczby przeslanej w akumulatorze do procedury
  CLR E			;opadajace zbocze na E zapisuje dana do wyswietlacza
  POP ACC		;przywroc poczatkowa wartosc akumulatora
  SWAP A		;zamien polowkami akumulator
  SETB E		;stan wysoki na E
  ANL A,#0F0H		;empty low
  CLR C			
  RRC A			;przesun akumulator w prawo
  ANL LCD,#087H		;wyzeruj bity d7-d4 w porcie LCD
  ORL LCD,A		;odwzorowuje na liniach D7-D4 mlodsze 4 bity liczby przeslanej w akumulatorze do procedury
  CLR E			;opadajace zbocze zapisuje dana do wyswietlacza			
  MOV A,#02H 			
  LCALL CZEKAJ		;odczekaj okolo 2 ms
RET			;powrot z procedury

ZAPISZ_ZNAK_DO_LCD: 
  SETB RS     ;procedura zapisu znaku z akumlatora do pamieci obrazu wyswietlacza LCD RS
  LCALL ZAPISZ_DO_LCD
RET

ZAPISZ_TEKST_DO_LCD: 
  MOV R6,#00H	;procedura zapisu tekstu do wyswietlacza LCD 
PP: 
  MOV A,R6				
  MOVC A,@A+DPTR			;przeslij bajt z pamieci kodu do akumulatora
  JZ KONIEC_ZAPISU			;jesli bajt rowny zero to koniec zapisu
  LCALL ZAPISZ_ZNAK_DO_LCD
  INC R6					
  AJMP PP				;skocz na poczatek petli 
  KONIEC_ZAPISU: RET

MOJE_ZNAKI_LCD: 
  MOV A,#40H			;ustaw tryb zapisu znakow do pamieci generatora znakow
  LCALL ZAPISZ_KOMENDE_LCD
  MOV DPTR,#ZNAKI_LCD		;wskaznik na wlasne znaki (ZNAKI_LCD)
  LCALL ZAPISZ_TEKST_DO_LCD
  MOV A,#80H			;powroc do trybu zapisow znakow do pamieci obrazu
  LCALL ZAPISZ_KOMENDE_LCD
RET