Inteligentny termostat - zapraszam do wspólnej twórczości

Question

Witajcie bracia i siostry ! Od pewnego czasu zafascynowałem się mikrokontrolerami, obkupiłem się w literaturę i podzespoły. Przeczytałem całą księgę Marcina Wiązani Programowanie mikrokontrolerów w języku BASCOM, zbudowałem prawie wszystkie przykładowe konstrukcje z tej książki ;-) Czas...

szeri88 · Accepted Answer

Witam,

Problem jest banalny - pomyliłeś transmisję 1-wire z I2C. Brakuje w kodzie konfiguracji magistrali I2C:

Config Sda = Portx.x
Config Scl = Portx.x

Pozdrawiam

crazy_phisic · Accepted Answer

Po odczycie ostatniego bajtu danych - w Twoim wypadku godziny powinieneś wystawić znacznik Nack.

shadow0013 · Answer

Witam. Niewiele mogę pomóc w programowaniu ale trzeba zacząc od założeń - może takie: w najgorszym wypadku można skorzystać z takiej oferty i adaptować do potrzeb:

Kuniarz · Answer

termometr z drugiego linka to nie problem, robiłem go studiując podręcznik. Termostat z pierwszego linka to już coś bliżej moich założeń, ale z tego co widzę to po odłączeniu zasilania układ się rozprogramuje...

shadow0013 · Answer

może jest zapisywane w eepromie? trzeba poszukać ne edw.com.pl robili podobne rzeczy jako sterowniki do akwarium może zamieścili źródła

Kuniarz · Answer

no w eepromie to bankowo, tylko pytanie - jak z poziomu Bascom'a zapisać coś w eepromie procesora ? Czy musi być do tego użyty zewnętrzny eeprom ?

marek_Łódź · Answer

Z helpu BASCOM Kod: text Rozwiń Zaznacz wszystko Kopiuj do schowkaDim Store As Eram Byte , B As Byte B = 10                                                      'assign value to b Store = B                                                   'value is stored in EPROM ! B = Store                                                   'get the value back proponuję też obejrzeć rozkaz writeeeprom

Kuniarz · Answer

o faktycznie, manual jest tak ogromny że nie zauważyłem takich bajeranckich rozkazów. Ok, jakie rozwiązanie zegara RTC polecacie ? Jeśli ma to być podtrzymywane bateryjnie to może PCF8583 ?

sylwunia35 · Answer

A może zegar z tej strony.

Kuniarz · Answer

stronka ciekawa, dziękuję, ale opisany tam zegar... zeruje się po zaniku prądu. W przypadku termostatu jest to niedopuszczalne, za dużo roboty z powtórnym ustawieniem wszystkich czasów i temperatur...
Szperając po Elektrodzie znalazłem też wiele postów na temat RTC DS1307, póki co zamówiłem jedne i drugie i mam nadzieję za 2 dni coś już wlutować i walczyć z tematem.

shadow0013 · Answer

DS1621 termostat i polski help do bascoma

Mad Bekon · Answer

Mnie się wydaje, że taki termostat to na tyle mało pracochłonne, że nie ma sensu korzystać z zewnętrznego RTC.
Wystarczy ustawić Timer i co jakiś czas zliczać te upływające sekundy / minuty / godziny

Pamiętaj, żeby twój termostat miał pętlę histerezy, w celu uniknięcia przełączania się przy wahaniach temperatury.

A jeśli chodzi o sterowanie, to takie pokrętło obrotowe, nazywa się enkoder.
Działa zazwyczaj tak, że, na 2 wyjściach po przekręceniu zmieniają się stany z 0 na 1 i na odwrót, z tym, że nie jednocześnie. Jeden z nich następuje wcześniej po tym można poznać kierunek obrotu.

Zachęcam też do spróbowania języka C pod te mikrokontrolery. Nic w tym bardziej skomplikowanego, czasami trzeba troszkę więcej samemu zrobić, ale za to oszczędność kodu wszystko wynagradza.
Pozdrawiam

Promuję tematy:
06.11.2019 Okresowe załączanie / wyłączanie projektora EPSON EB-535W
Mam na sprzedaż:
29.04.2016 PCB do projektu UniSolder 5.2
02.04.2016 Precyzyjna drabinka pomiarowa CADDOCK 1776-C62

Kuniarz · Answer

wszystko OK, ale cały czas wracamy do punktu wyjścia - urzadzenie musi mieć bateryjne podtrzymania zegara.

olekewaagata · Answer

Zastosuj PCF8583 tam masz zegar czasu i jednoczesnie dużo wolnej pamięci , gdzie będziesz mógł zapisać nastawy. Jeśli teraz dasz podtrzymanie PCF-a z pastylki 3V to i nastawy zachowają sie w PCF-ie. Nie będziesz wtedy musiał stosować innego eepromu do zapamiętywania nastawów.

Mad Bekon · Answer

ale i tak pozostaje problem podtrzymania baterii.
Po co wkładać dodatkowy układ w układ?
W Atmegach jest wystarczająco eepromu, żeby trzymać ustawienia. Wsadzić pastylke do podtrzymywania, na jedno wejście zrobić czujnik zasilania z sieci. Jak braknie prądu to niech procek idzie spać i tylko niech czas zlicza. Konsumpcja takiego układu jest bardzo niska.

Promuję tematy:
06.11.2019 Okresowe załączanie / wyłączanie projektora EPSON EB-535W
Mam na sprzedaż:
29.04.2016 PCB do projektu UniSolder 5.2
02.04.2016 Precyzyjna drabinka pomiarowa CADDOCK 1776-C62

Kuniarz · Answer

hmmm... mógłbyś rozwinąć myśl i może podeprzeć listingiem/schematem ? brak RTC zmniejszy koszt układu i go uprości (czytaj - mniej pierdół do zakłucania się...)

Kuniarz · Answer

Do układu doszedł właśnie RTC, oto schemat po poprawkach:

a oto skrypt ktory teoretycznie powinien czytac DS1307 i wyświetlić odczyt na LCD:

$regfile = "m8def.dat"
$crystal = 8000000
Config 1wire = Portd.1
Config Lcd = 16 * 2
Config Lcdpin = Pin , Db4 = Portc.3 , Db5 = Portc.2 , Db6 = Portc.1 , Db7 = Portc.0 , E = Portc.4 , Rs = Portc.5
Dim Sekundy As Byte
Dim Minuty As Byte
Dim Godziny As Byte
Cursor Off Noblink
Do
   I2cstart
   I2cwbyte 208
   I2cwbyte 0
   I2cstart
   I2cwbyte 209
   I2crbyte Sekundy , Ack
   I2crbyte Minuty , Ack
   I2crbyte Godziny , Ack
   I2cstop
   Sekundy = Makedec(sekundy)
   Minuty = Makedec(minuty)
   Godziny = Makedec(godziny)
   Lcd Godziny ; ":" ; Minuty ; ":" ; Sekundy
   Waitms 100
Loop
End

podczas kompilacji wywala sie błąd "Unknow Statement [.EQU not found for PORTA:" - błędów jest kilka, zmienia sie ostatni wyraz, po załadowaniu programu na wyswietlaczu śmieci.

gdzie mam coś nie teges ?

Pracownia na fejsbuku, zapraszam.

Jutuber : https://www.youtube.com/@Robert_Kuna

Pomogłem? Kup mi kawę.

Promuję tematy:
26.11.2025 Samodzielna budowa tymczasowej rozdzielnicy budowlanej.
18.06.2025 INTEX SF90220-1 – jak uruchomiłem martwą pompę basenową alternatywnym sposobem
24.04.2025 Prototyp urządzenia elektronicznego - jak powstaje, VIDEO
28.12.2024 Przystosowanie ładowarki PARKSIDE X12V Team do zasilania Off Grid (24V)
25.06.2023 Prosty tester elektroniki FCT / EOL - opis, budowa, działanie.

Kuniarz · Answer

Dziękuję za porady, kod po poprawce wygląda tak :

$regfile = "m8def.dat"
$crystal = 8000000
Config Sda = Portd.0
Config Scl = Portd.1
Config Lcd = 16 * 2
Config Lcdpin = Pin , Db4 = Portc.3 , Db5 = Portc.2 , Db6 = Portc.1 , Db7 = Portc.0 , E = Portc.4 , Rs = Portc.5
Dim Sekundy As Byte
Dim Minuty As Byte
Dim Godziny As Byte
Cursor Off Noblink
'Godziny = 10
'Minuty = 45
'Sekundy = 10
'Godziny = Makebcd(godziny)
'Minuty = Makebcd(minuty)
'Sekundy = Makebcd(sekundy)
'I2cstart
'I2cwbyte 208
'I2cwbyte 0
'I2cwbyte Sekundy
'I2cwbyte Minuty
'I2cwbyte Godziny
'I2cstop

Do
   I2cstart
   I2cwbyte 208
   I2cwbyte 0
   I2cstart
   I2cwbyte 209
   I2crbyte Sekundy , Ack
   I2crbyte Minuty , Ack
   I2crbyte Godziny , Nack
   I2cstop
   Sekundy = Makedec(sekundy)
   Minuty = Makedec(minuty)
   Godziny = Makedec(godziny)
   Cls
   Lcd Godziny ; ":" ; Minuty ; ":" ; Sekundy
   Waitms 100
Loop
End

(wyremowane są komendy zapisu, bez tego zegra nie liczy, ale wystarczy zrobic to jednorazowo)

Zabieram się zatem za pisanie kodu z opcją ustawiania godziny i daty

Pracownia na fejsbuku, zapraszam.

Jutuber : https://www.youtube.com/@Robert_Kuna

Pomogłem? Kup mi kawę.

Promuję tematy:
26.11.2025 Samodzielna budowa tymczasowej rozdzielnicy budowlanej.
18.06.2025 INTEX SF90220-1 – jak uruchomiłem martwą pompę basenową alternatywnym sposobem
24.04.2025 Prototyp urządzenia elektronicznego - jak powstaje, VIDEO
28.12.2024 Przystosowanie ładowarki PARKSIDE X12V Team do zasilania Off Grid (24V)
25.06.2023 Prosty tester elektroniki FCT / EOL - opis, budowa, działanie.

Kuniarz · Answer

oook, do schematu doszły trzy przyciski zwierane do masy na liniach PB3-PB5 poniżej wrzucam kod który pozwala na wyświetlenie daty i czasu oraz zaprogramowanie. W celu wejścia w programowanie należy przycisnac na 2 sekundy przycisk Nie rozwiązałem jeszcze dwóch problemów: - niektóre miesiące mają 30 inne 31 dni (to nie problem...) - jak obliczyć który rok jest przestępnym ? (tak teraz sobie myślę że programowanie daty należy rozpocząć od roku ) Kod: text Rozwiń Zaznacz wszystko Kopiuj do schowka$regfile = m8def.dat $crystal = 8000000 Config Sda = Portd.0 Config Scl = Portd.1 Config Lcd = 16 * 2 Config Lcdpin = Pin , Db4 = Portc.3 , Db5 = Portc.2 , Db6 = Portc.1 , Db7 = Portc.0 , E = Portc.4 , Rs = Portc.5 Config Pinb.3 = Input Config Pinb.4 = Input Config Pinb.5 = Input Dim Sekundy As Byte Dim Minuty As Byte Dim Godziny As Byte Dim Dzientygodnia As Byte Dim Dzien As Byte Dim Miesiac As Byte Dim Rok As Byte Dim Dalej As Byte                                           'zmienna pomocnicza przy programowaniu Dim A As Byte                                               'zmienna pomocnicza petli Dim N_dzien(99)as Byte                                      'nastawa dnia zdarzenia Dim N_godzina(99)as Byte                                    'nastawa godziny Dim N_minuty(99)as Byte                                     'nastawa minut zdarzenia Dim N_temperatura(99) As Byte                               'jaka ma byc temperatura (jesli zero to wylaczenie) Dalej = 0 Declare Sub Rtc_odczyt Declare Sub Rtc_zapis Declare Sub Rtc_wyswietl Declare Sub Programowanie Declare Sub Zerowanie_nastaw Cursor Off Noblink S_wiecej Alias Pinb.3 S_mniej Alias Pinb.4 S_wybierz Alias Pinb.5 Set Portb.3 Set Portb.4 Set Portb.5 Zerowanie_nastaw Do    If S_wybierz = 0 Then       Wait 2          If S_wybierz = 0 Then             Programowanie          End If    End If    Rtc_odczyt    Rtc_wyswietl    Waitms 100    Loop End Rtc_odczyt:    I2cstart    I2cwbyte 208    I2cwbyte 0    I2cstart    I2cwbyte 209    I2crbyte Sekundy , Ack    I2crbyte Minuty , Ack    I2crbyte Godziny , Ack    I2crbyte Dzientygodnia , Ack    I2crbyte Dzien , Ack    I2crbyte Miesiac , Ack    I2crbyte Rok , Nack    I2cstop    Sekundy = Makedec(sekundy)    Minuty = Makedec(minuty)    Godziny = Makedec(godziny)    Dzientygodnia = Makedec(dzientygodnia)    Dzien = Makedec(dzien)    Miesiac = Makedec(miesiac)    Rok = Makedec(rok) Return Rtc_zapis:    Godziny = Makebcd(godziny)    Minuty = Makebcd(minuty)    Sekundy = Makebcd(sekundy)    Dzientygodnia = Makebcd(dzientygodnia)    Dzien = Makebcd(dzien)    Miesiac = Makebcd(miesiac)    Rok = Makebcd(rok)    I2cstart    I2cwbyte 208    I2cwbyte 0    I2cwbyte Sekundy    I2cwbyte Minuty    I2cwbyte Godziny    I2cwbyte Dzientygodnia    I2cwbyte Dzien    I2cwbyte Miesiac    I2cwbyte Rok    I2cstop Return Rtc_wyswietl:    Cls    Lcd Godziny ; : ; Minuty ; : ; Sekundy    Lowerline    Lcd Dzien ; . ; Miesiac ; . ; Rok ; dz. ; Dzientygodnia Return Programowanie:    Dalej = 0    Cls    Lcd --PROGRAMOWANIE--    Do       Waitms 25    Loop Until S_wybierz = 1                                 'czekamy na puszczenie wybierz Do    Lowerline    If Godziny

crazy_phisic · Answer

Zapis z noty katalogowej ds1307: The end of the month date is automatically adjusted for months with fewer than 31 days, including corrections for leap year. Spooory juz się listing zrobił z ciekawości ile zajmuje?

Kuniarz · Answer

hmmm... jestem juz w domu wiec listingu nie zmierzę... ale faktycznie wygląda okazale

co do DS1307 to faktycznie w samym układzie data pójdzie poprawnie, chodziło mi tylko o programowanie przez użytkownika, gdyż teoretycznie w tej chwili można ustawić 31.02.2007 i zapisać w DS (swoją drogą ciekawe jak sie zachowa

)

Kuniarz · Answer

poprawiłem kod, w tej chwili rozpoznaje miesiące 30 i 31 dniowe, temat roku przestępnego odpuściłem - układ sam to poprawi...

...ale, kurcze pojawił się z rana kolejny problem, mianowicie wyobrażałem sobie że DS1307 w rejestrze DAY zapamiętuje konkretny dzien tygodnia dla danej daty (np. że 30 marca 2007 jest piątek), a tu nici , bo DAY to licznik dni po przejściu godziny przez 0:00 ...
Ma ktoś pomysł jak obliczyć że np. po ustawieniu daty na 11.10.2007 będzie czwartek (w zmienną "dzientygodnia" wpisać np. 4) ??
... teoretycznie przy programowaniu mozna spytać użytkownika o dzień, ale przeca termostat miał być dla blondynek ;-)

Kuniarz · Answer

Dobra, dałem sobie spokój, to jest nie do zrobienia w bascomie... kupiłem w BricoMarche taką czasówkę okręcaną co można dni tygodnia ustawić i podłączyłem to pod bojler.
Temat do zamknięcia.

zumek · Answer

Eeeeee..... tam , za szybko sie poddałeś Wzór jest nieziemsko prosty dzien_tygodnia=((rok-1)+((rok-1)/4)+kolejny_dzien_roku) MOD 7 Wynik to: 0-sobota , 1-niedziela, ... ,6-piątek , a kolejny_dzien_roku to np. dziś mamy 91 dzień w tym roku To tyle Piotrek EDIT: Poprawiłem dzielaenie , bo było /2 , a powinno być /4

LichyiChydy · Answer

Jak otrzymać który jest to dzień w roku z daty?

zumek · Answer

Odpowiedź brzmi : tabela Kod: text Rozwiń Zaznacz wszystko Kopiuj do schowka Tabela: Data 0% , 31% , 59% , 90% , 120% , 151% , 181% , 212% , 243% , 273% , 304% , 334% Nie zapominamy oczywiście , o uwzględnieniu w obliczeniach , roku przestępnego Piotrek

WaldekPrzybyłek · Answer

Zumek - jesteś wielki - jeśli nie największy...
Podziwiam twoją wiedzę oraz chęć pomocy "malućkim". Dla mnie jesteś "Guru".
Mam tylko nadzieję , że jeśli kiedykolwiek "wyskoczę" z jakimś błachym problemem , będziesz miał na tyle cierpliwości aby mi pomóc.
Oby zdrowie i zapał Cię nie opuściły nigdy.
Pozdrawiam całe forum.
P.s. Bez poprawki na 1 kwietnia.

Kuniarz · Answer

Oczywiście to że się poddałem było żarcikiem primaaprilisowym ;-)

Dziękuję za wskazówki odnośnie roku przestępnego itp. póki co ich nie zastosowałem, wrócę do tematu po stworzeniu "rdzenia" programu.
Mało miałem ostatnio czasu, ale zoptymalizowałem trochę kod dodając procedury. Dodałem w menu opcję wyboru czy programujemy zegar czy już gotowe nastawy termostatu. Wklejam kolejny roboczy kod dla zainteresowanych.
Spróbuję jutro dokończyć podprogram ustawiania nastaw, zrobię zapis do EEPROM no i pozostanie później w główną pętlę dać sprawdzanie czy godzina wskazuje na jakąś nastawę no i czas podłączyć śjakąś grzałkę ;-)

$regfile = "m8def.dat"
$crystal = 8000000
Config Sda = Portd.0
Config Scl = Portd.1
Config Lcd = 16 * 2
Config Lcdpin = Pin , Db4 = Portc.3 , Db5 = Portc.2 , Db6 = Portc.1 , Db7 = Portc.0 , E = Portc.4 , Rs = Portc.5
Config Pinb.3 = Input
Config Pinb.4 = Input
Config Pinb.5 = Input

Dim Sekundy As Byte
Dim Minuty As Byte
Dim Godziny As Byte
Dim Dzientygodnia As Byte
Dim Dzien As Byte
Dim Miesiac As Byte
Dim Rok As Byte
Dim Nazwa_dnia(7)as String * 9
Dim Menu1(2)as String * 16
Dim Menu As Byte
Dim Dalej As Byte                                           'zmienna pomocnicza przy programowaniu
Dim A As Byte                                               'zmienna pomocnicza petli
Dim Nastawa As Byte                                         'numer nastawy (1-99)


Dim N_dzien(99) As Byte                                     'nastawa dnia
Dim N_godzina(99) As Byte
Dim N_minuty(99) As Byte
Dim N_temperatura(99) As Byte


Nazwa_dnia(1) = "poniedz."
Nazwa_dnia(2) = "wtorek"
Nazwa_dnia(3) = "sroda"
Nazwa_dnia(4) = "czwartek"
Nazwa_dnia(5) = "piatek"
Nazwa_dnia(6) = "sobota"
Nazwa_dnia(7) = "niedziela"

Menu1(1) = "   termostat    "
Menu1(2) = " data i godzina "
Menu = 2

Dalej = 0

Declare Sub Rtc_odczyt
Declare Sub Rtc_zapis
Declare Sub Rtc_wyswietl
Declare Sub Programowanie
Declare Sub Zerowanie_nastaw
Declare Sub Zmiana(zmienna As Byte , Byval Minimum As Integer , Byval Maximum As Byte)


Cursor Off Noblink

S_wiecej Alias Pinb.3
S_mniej Alias Pinb.4
S_wybierz Alias Pinb.5

Set Portb.3
Set Portb.4
Set Portb.5


Do
   If S_wybierz = 0 Then
      Wait 2
         If S_wybierz = 0 Then
            Programowanie
         End If
   End If
   Rtc_odczyt
   Rtc_wyswietl
   Waitms 100
   Loop
End

Zerowanie_nastaw:
For A = 0 To 99
   N_dzien(a) = 0
   N_godzina(a) = 0
   N_minuty(a) = 0
   N_temperatura(a) = 0
Next A
Return

Rtc_odczyt:
   I2cstart
   I2cwbyte 208
   I2cwbyte 0
   I2cstart
   I2cwbyte 209
   I2crbyte Sekundy , Ack
   I2crbyte Minuty , Ack
   I2crbyte Godziny , Ack
   I2crbyte Dzientygodnia , Ack
   I2crbyte Dzien , Ack
   I2crbyte Miesiac , Ack
   I2crbyte Rok , Nack
   I2cstop
   Sekundy = Makedec(sekundy)
   Minuty = Makedec(minuty)
   Godziny = Makedec(godziny)
   Dzientygodnia = Makedec(dzientygodnia)
   Dzien = Makedec(dzien)
   Miesiac = Makedec(miesiac)
   Rok = Makedec(rok)
Return

Rtc_zapis:
   Godziny = Makebcd(godziny)
   Minuty = Makebcd(minuty)
   Sekundy = Makebcd(sekundy)
   Dzientygodnia = Makebcd(dzientygodnia)
   Dzien = Makebcd(dzien)
   Miesiac = Makebcd(miesiac)
   Rok = Makebcd(rok)
   I2cstart
   I2cwbyte 208
   I2cwbyte 0
   I2cwbyte Sekundy
   I2cwbyte Minuty
   I2cwbyte Godziny
   I2cwbyte Dzientygodnia
   I2cwbyte Dzien
   I2cwbyte Miesiac
   I2cwbyte Rok
   I2cstop
Return

Rtc_wyswietl:

   Cls
   Lcd Godziny ; ":" ; Minuty ; ":" ; Sekundy
   Lowerline
   Lcd Dzien ; "." ; Miesiac ; "." ; Rok ; "-" ; Nazwa_dnia(dzientygodnia)
Return

Programowanie:
Dalej = 0
Cls
Lcd "--PROGRAMOWANIE--"
Do
Loop Until S_wybierz = 1                                    'czekamy na puszczenie "wybierz"
Do
   Lowerline
   Lcd Menu1(menu)
   Call Zmiana(menu , 1 , 3)
Loop Until Dalej = 1
Dalej = 0
Cls
Lcd "--PROGRAMOWANIE--"
If Menu = 1 Then Goto Termostat
If Menu = 2 Then Goto Czas

Termostat:
Waitms 25
Do
Loop Until S_wybierz = 1                                    'czekamy na puszczenie "wybierz"
Nastawa = 1
Cls
Lcd "Nastawa dla"
Do
   Lowerline
   Lcd "dnia : " ; Nazwa_dnia(dzientygodnia) ; "    "
   Call Zmiana(dzientygodnia , 1 , 8)
Loop Until Dalej = 1
Dalej = 0
N_dzien(nastawa) = Dzientygodnia
Waitms 25
Do
Loop Until S_wybierz = 1                                    'czekamy na puszczenie "wybierz"
Cls
Lcd "ustaw godzine"
Do
   Lowerline
   Lcd "wlaczenia: " ; Godziny ; " "
   Call Zmiana(godziny , 0 , 24)
Loop Until Dalej = 1
Dalej = 0
N_godzina(nastawa) = Godziny

Waitms 25
Do
Loop Until S_wybierz = 1                                    'czekamy na puszczenie "wybierz"
Cls
Lcd "ustaw minuty"
Minuty = 0
Do
   Lowerline
   Lcd "wlaczenia: " ; Minuty ; " "
   Call Zmiana(minuty , 0 , 60)
Loop Until Dalej = 1
Dalej = 0
N_minuty(nastawa) = Minuty
Waitms 25
Do
Loop Until S_wybierz = 1                                    'czekamy na puszczenie "wybierz"
'temperatura czy wylaczenie ? - dopisac

A = 20
Cls
Lcd "wymagana"
Do
   Lowerline
   Lcd "temperatura: " ; A ; " "
   Call Zmiana(a , 20 , 91)
Loop Until Dalej = 1
Dalej = 0
N_temperatura(nastawa) = A

Goto Koniec

Czas:
Waitms 25
Do
Loop Until S_wybierz = 1                                    'czekamy na puszczenie "wybierz"

Do
   Lowerline
   Lcd "godzina: " ; Godziny ; " "
   Call Zmiana(godziny , 0 , 24)
Loop Until Dalej = 1
Dalej = 0

Cls
Lcd "--PROGRAMOWANIE--"
Do
   Waitms 25
Loop Until S_wybierz = 1

Do
   Lowerline
   Lcd "minuty: " ; Minuty ; " "
   Call Zmiana(minuty , 0 , 60)
Loop Until Dalej = 1
Dalej = 0

Cls
Lcd "--PROGRAMOWANIE--"
Do
   Waitms 25
Loop Until S_wybierz = 1

Do
   Lowerline
   If Rok < 10 Then
      Lcd "rok: 200" ; Rok
   Else
      Lcd "rok: 20" ; Rok
   End If
   Call Zmiana(rok , 0 , 50)
Loop Until Dalej = 1
Dalej = 0

Cls
Lcd "--PROGRAMOWANIE--"
Do
   Waitms 25
Loop Until S_wybierz = 1

Do
   Lowerline
   Lcd "miesiac: " ; Miesiac ; " "
   Call Zmiana(miesiac , 1 , 13)
Loop Until Dalej = 1
Dalej = 0

Cls
Lcd "--PROGRAMOWANIE--"
Do
   Waitms 25
Loop Until S_wybierz = 1

Do
   Lowerline
   Lcd "dzien: " ; Dzien ; " "
   If Miesiac = 1 Or Miesiac = 3 Or Miesiac = 5 Or Miesiac = 7 Or Miesiac = 8 Or Miesiac = 10 Or Miesiac = 12 Then
      Call Zmiana(dzien , 1 , 32)
   Else
      Call Zmiana(dzien , 1 , 31)
   End If
Loop Until Dalej = 1
Dalej = 0

Cls
Lcd "--PROGRAMOWANIE--"
Do
   Waitms 25
Loop Until S_wybierz = 1

Do
   Lowerline
   Lcd "dzien :" ; Nazwa_dnia(dzientygodnia) ; "    "
   Call Zmiana(dzientygodnia , 1 , 8)
Loop Until Dalej = 1
Dalej = 0

Sekundy = 0
Rtc_zapis

Koniec:
Return

Sub Zmiana(zmienna As Byte , Byval Minimum As Integer , Byval Maximum As Byte)

   If S_wybierz = 0 Then
      Waitms 25
      If S_wybierz = 0 Then
         Dalej = 1
      End If
   End If

   If S_wiecej = 0 Then
      Waitms 25
      If S_wiecej = 0 Then
         Incr Zmienna
         If Zmienna = Maximum Then
            Zmienna = Minimum
         End If
         Waitms 200
      End If
   End If
   If S_mniej = 0 Then
      Waitms 25
      If S_mniej = 0 Then
         If Zmienna = Minimum Then
            Zmienna = Maximum
         End If
         Decr Zmienna
         Waitms 200
      End If
   End If

End Sub

Pracownia na fejsbuku, zapraszam.

Jutuber : https://www.youtube.com/@Robert_Kuna

Pomogłem? Kup mi kawę.

Promuję tematy:
26.11.2025 Samodzielna budowa tymczasowej rozdzielnicy budowlanej.
18.06.2025 INTEX SF90220-1 – jak uruchomiłem martwą pompę basenową alternatywnym sposobem
24.04.2025 Prototyp urządzenia elektronicznego - jak powstaje, VIDEO
28.12.2024 Przystosowanie ładowarki PARKSIDE X12V Team do zasilania Off Grid (24V)
25.06.2023 Prosty tester elektroniki FCT / EOL - opis, budowa, działanie.

Kuniarz · Answer

Prace nad projektem trwają nadal, póki co mam zrobione:

- programowanie daty i godziny (jeszcze bez obliczania roku przestępnego, zwalilem to na RTC sprzetowy ;-)

)

- programowanie 99 nastaw czyli : dzien którego dotyczy nastawa, godzina i minuty, zadana temperatura 30-90 stopni (lub wyłaczenie). Program automatycznie sprawdza która nastawa jest kolejna

- przegląd nastaw (program sprawdza ile zostało zaprogramowanych i wyswietla tylko ten zakres)

- kasowanie wszystkich nastaw

nastawy zapisywane sa w eeprom, tak wiec po zaniku zasilania i ponownym wlaczeniu wszystko ladnie pamieta, zegar podtrzymany bateria wiec rowniez odporny na brak zasilania.

Aktualnie podchodzę do spraw końcowych, czyli czujnik temperatury (DS18s20 - tu nie spodziewam się problemów) oraz element wykonawczy.

Mam tutaj pytanie do szanownego grona odnośnie tego ostatniego, mianowicie czy bojler (lub grzejnik) włączać przekaźnikiem czy triakiem ? Jakieś propozycje jednego lub drugiego elementu ?
Dodam, że nie będzie to praca ciągła i szybko zmienna. Wiadomo że w takim powiedzmy 100l bojlerze temperatura wody ma dużą bezwładność, więc jeśli urządzenie co 5-10 minut zareaguje na zmianę to w zupełności wystarczy.

Pracownia na fejsbuku, zapraszam.

Jutuber : https://www.youtube.com/@Robert_Kuna

Pomogłem? Kup mi kawę.

Promuję tematy:
26.11.2025 Samodzielna budowa tymczasowej rozdzielnicy budowlanej.
18.06.2025 INTEX SF90220-1 – jak uruchomiłem martwą pompę basenową alternatywnym sposobem
24.04.2025 Prototyp urządzenia elektronicznego - jak powstaje, VIDEO
28.12.2024 Przystosowanie ładowarki PARKSIDE X12V Team do zasilania Off Grid (24V)
25.06.2023 Prosty tester elektroniki FCT / EOL - opis, budowa, działanie.

Inteligentny termostat - zapraszam do wspólnej twórczości

Jak zbudować inteligentny termostat na ATmega8 z podtrzymywanym zegarem, zapisem nastaw i bezpiecznym sterowaniem grzałką?

Post #1

Post #2

Post #3

Post #4

Post #5

Post #6

Post #7

Post #8

Post #9

Post #10

Post #11

Post #12

Post #13

Post #14

Post #15

Post #16

Post #17

Post #18

Post #19

Post #20

Post #21

Post #22

Post #23

Post #24

Post #25

Post #26

Post #27

Post #28

Post #29

Post #30

Podsumowanie tematu