OpenBeken Konfigurowanie przycisków Otwórz/Zatrzymaj/Zamknij na przełączniku Sma

Name: OpenBeken Konfigurowanie przycisków Otwórz/Zatrzymaj/Zamknij na przełączniku Sma
Uploaded: 2023-04-23T19:58:57+02:00
Description: Sflashowałem i częściowo skonfigurowałem Smart Life Switch, ale mam problem z wyzwalaniem skryptów lub poleceń backlog w przypadku kliknięcia przycisku. Znam Tasmota, ale nigdy wcześniej nie korzystałem z OpenBeken. Oto urządzenie ze zdjętym panelem przednim: Aktualna konfiguracja to przycisk...

Question

Sflashowałem i częściowo skonfigurowałem Smart Life Switch, ale mam problem z wyzwalaniem skryptów lub poleceń backlog w przypadku kliknięcia przycisku. Znam Tasmota, ale nigdy wcześniej nie korzystałem z OpenBeken. Oto urządzenie ze zdjętym panelem przednim: Aktualna konfiguracja to przycisk...

p.kaczmarek2 · Accepted Answer

Może byłoby lepiej, gdybym po prostu stworzył dedykowany sterownik do rolet? Wygląda na to, że twój przypadek użycia jest bardzo ogólny.

Dodano po 3 [minutach]:

Oto nieprzetestowany (UWAGA!) pomysł na scenariusz:



// Channel 10 - Relay 1
// Channel 11 - Relay 2

alias Set_Up setChannel 10 0; setChannel 11 1
alias Set_Down setChannel 10 1; setChannel 11 0
alias Set_None setChannel 10 0; setChannel 11 0

// command "Start_Opening" will first kill other script threads, and start with clear open
alias Start_Opening backlog stopAllScripts; startScript autoexec.bat openShutter
// command "Start_Closing" will first kill other script threads, and start with clear close
alias Start_Closing backlog stopAllScripts; startScript autoexec.bat closeShutter
// command "Start_Closing" will first kill other script threads, and then stop
alias Stop_All backlog stopAllScripts; Set_None

// create GUI buttons for HTTP panel
startDriver httpButtons
setButtonEnabled 0 1
setButtonLabel 0 "Open"
setButtonCommand 0 Start_Opening

setButtonEnabled 1 1
setButtonLabel 1 "Close"
setButtonCommand 1 Start_Closing

setButtonEnabled 2 1
setButtonLabel 2 "Stop"
setButtonCommand 2 Stop_All

// link the same commands to physical button on GPIO pins
// 8 and 9 are GPIO indices, like P9, etc
addEventHandler OnClick 8 Start_Opening
addEventHandler OnClick 9 Start_Closing
addEventHandler OnClick 10 Stop_All

// do not proceed
return

// Script thread for opening
openShutter:
// setup none
Set_None
// wait 0.1 seconds
delay_s 0.1
// setup up
Set_Up
// wait 10 seconds
delay_s 10
Set_None
// done
return

// Script thread for closing
closeShutter:
// setup none
Set_None
// wait 0.1 seconds
delay_s 0.1
// setup down
Set_Down
// wait 10 seconds
delay_s 10
Set_None
// done
return

p.kaczmarek2 · Answer

Cześć, po pierwsze, jakie zachowanie próbujesz osiągnąć? Czy to ma być sterownik migawki? Zamiast delay_s 3 w backlog powinieneś użyć addRepeatingEvent 3 1 , delay_s może teraz działać w wątku skryptu, a nie w backlogu. Jeśli chcesz, mogę napisać następujący skrypt: Nie używałbym do tego etykiet kanałów. Użyłbym przycisków skryptowych. Ale czy to kontroler migawki? Dziś wieczorem zobaczę, co mogę dla ciebie zrobić.

richardsg307 · Answer

Tak, w koncepcji jest to „migawka”, ale w tym przypadku otwiera/zamyka świetlik.

Jest to system 4-przewodowy - uziemienie, neutralny, na żywo/otwarty i na żywo/zamknięty. Potrzebuję więc jednego z 2 przekaźników, ale zdecydowanie nie obu. Sposób działania przełącznika z oprogramowaniem Tuya polegał na tym, że po około 10 sekundach (przypuszczalnie wystarczająco długo, aby okno mogło się otworzyć/zamknąć, oba przekaźniki zgasły (chyba w celu oszczędzania energii i odizolowania mechanizmu).
W systemie plików stworzyłem 3 proste pliki skryptów. np. dla zamknięcia, plik close.bat zapewnia, że przekaźnik Open jest wyłączony przed włączeniem przekaźnika Close, odczekanie 10 sekund, a następnie wyłączenie. Następnie włącza kanał zatrzymania lub diodę LED na zaledwie 3 sekundy.

/ Close - Turns Open relay off, then turns Close relay on for 10s
// Then shows Stop LED for 3s
setchannel 1 0
setchannel 2 0
delay_ms 250
setchannel 3 1
delay_s 10
setchannel 3 0
setchannel 2 1
delay_s 3
setchannel 2 0

Podobnie dla skryptów stop.bat i open.bat. Wszystkie działają, gdy naciskam przycisk „Zapisz, uruchom plik jako wątek skryptu” w interfejsie internetowym.
Nie mogę zrozumieć, jak uruchomić skrypty po kliknięciu przycisku. Próbowałem dodać procedury obsługi zdarzeń w pliku autoexec.bat, ale wydaje się, że nic nie działa.

// Add names to the buttons
setChannelLabel 1 Open 1
setChannelLabel 2 Stop 1
setChannelLabel 3 Close 1
setChannel 1 0
setChannel 2 0
setChannel 3 1
echo "Closing Skylight"
delay_s 10
setChannel 3 0
echo "Loading Event Handlers"
addEventHandler OnClick 1 startScript open.bat * 123

Po prostu czegoś mi brakuje, więc przydałoby się kilka wskazówek we właściwym kierunku.
Na marginesie - gdzie zapisywane są echa?
Dzięki

Promuję tematy:
19.04.2023 Programowanie sterownika rolet Skylight, skrypty OpenBeken, uwolnienie od Chińskiej chmury

p.kaczmarek2 · Answer

Ok, przygotuję dla Ciebie przykład, ale najpierw czy możesz mi powiedzieć, co powinno się stać, jeśli użytkownik naciśnie przycisk otwórz, a następnie po 1 sekundzie zamknij?
a) otwarcie powinno przerwać, a zamknięcie powinno rozpocząć
b) open powinien kontynuować i zignorować żądanie zamknięcia

richardsg307 · Answer

Dzięki. Myślę, że opcja a).

richardsg307 · Answer

Dam mu szansę, gdy go zrozumiem. W tej chwili mam przełącznik zamontowany w skrzynce testowej i nic nie jest podłączone do przekaźników, więc powinno być bezpiecznie!
Zdam raport.

Aktualizacja:
Prawie gotowe! Mam 3 pytania...
1) [Rozwiązane] Czy mogę wyłączyć domyślne przyciski, skoro autoexec utworzył własne? Problem polega na tym, że z domyślnymi przyciskami mogę mieć jednocześnie włączone przekaźniki Otwórz i Zamknij! Czy mogę je wyłączyć lub sprawić, by uruchamiały te same procedury obsługi zdarzeń, co przyciski HTTP GUI? (Znaleziono - polecenie setChannelVisible).
2) [Rozwiązany] Jaki jest numer pinu RXD1 do użycia w poleceniu addEventHandler OnClick. RXD1 jest wejściem z przycisku Pause/Stop na moim panelu! (Znalazłem - RXD1 to pin 10, a TXD1 to pin 11).
3) [Rozwiązano] Połączyłem się przez MQTT z Home Assistant i użyłem kodu YAML podanego na stronie HA Cfg, ale to pozwala mi tylko włączać lub wyłączać poszczególne przekaźniki. Jak mogę wysłać polecenie, aby aktywować skrypty Otwórz lub Zamknij? (Znalazłem - opublikuj temat MQTT cmnd/skylight/Start_Opening, gdzie Start_Opening to alias procedury otwierającej świetlik).

Jutro podłączę otwieracz i jeśli wszystko będzie w porządku, prześlę całość jako rozbiórkę.

Promuję tematy:
19.04.2023 Programowanie sterownika rolet Skylight, skrypty OpenBeken, uwolnienie od Chińskiej chmury

richardsg307 · Answer

>>20545714 Wszystko posortowane teraz i przesłałem rozbiórkę ze wszystkimi konfiguracjami i kodem. Myślę, że w tej chwili jest jeszcze w toku. Czy dostanę darmową kartę SD?

p.kaczmarek2 · Answer

Tak, wykonałeś świetną robotę z tym przewodnikiem. Wyślemy Ci wiadomość na PW. Pamiętaj, że możesz też opublikować kolejny.

mbolty · Answer

Witam, posiadam moduł cb2s. Próbowałem wprowadzić kod, aby móc używać go jako modułu migawki, dodając drugi przekaźnik i drugi przycisk, ale u mnie to nie działa. kod pliku autoexec.bat jest następujący:

// Channel 1 - Relay 1
// Channel 2 - Relay 2
setChannelVisible 1 0
setChannelVisible 2 0

alias Set_Up setChannel 1 0; setChannel 2 1
alias Set_Down setChannel 2 0; setChannel 1 1
alias Set_None setChannel 1 0; setChannel 2 0

// command "Start_Opening" will first kill other script threads, and start with clear open
alias Start_Opening backlog stopAllScripts; startScript autoexec.bat openShutter
// command "Start_Closing" will first kill other script threads, and start with clear close
alias Start_Closing backlog stopAllScripts; startScript autoexec.bat closeShutter
// command "Start_Closing" will first kill other script threads, and then stop
alias Stop_All backlog stopAllScripts; set_none

// create GUI buttons for HTTP panel
startDriver httpButtons
setButtonEnabled 0 1
setButtonLabel 0 "Open"
setButtonCommand 0 Start_Opening

setButtonEnabled 1 1
setButtonLabel 1 "Close"
setButtonCommand 1 Start_Closing

setButtonEnabled 2 1
setButtonLabel 2 "Stop"
setButtonCommand 2 Stop_All

// link the same commands to physical button on GPIO pins
// 8 and 9 are GPIO indices, like P9, etc
addEventHandler OnClick 24 Start_Opening
addEventHandler OnClick 26 Start_Closing
addEventHandler OnClick 10 Stop_All

// do not proceed
return

// Script thread for opening
openShutter:
// setup none
set_none
// wait 0.1 seconds
delay_s 0.1
// set up
Set_Up
//wait 10 seconds
delay_s 10
set_none
// done
return

// Script thread for closing
closeShutter:
// setup none
set_none
// wait 0.1 seconds
delay_s 0.1
// setup down
Set_Down
// wait 10 seconds
delay_s 10
set_none
// done
return

Ale żadne z wyjść nie jest aktywne.
Proszę, doceniam każdą pomoc

Dziennik:

Info:CMD:CMD_StartScript: uruchomiono autoexec.bat na etykiecie openShutter
Info:CMD:[Wynik polecenia WebApp Cmd 'Start_Opening'] OK
Info:GEN:Brak zmian w kanale 1 (nadal ustawiony na 0) - ignorowanie

Info:GEN:Brak zmian w kanale 1 (nadal ustawiony na 0) - ignorowanie

Info: MAIN:Time 451, bezczynny 160941/s, wolny 68640, MQTT 1(2), bWi

p.kaczmarek2 · Answer

Edytuj post i użyj znacznika kodu, aby opublikować kod.

Załącz zrzut ekranu konfiguracji pinów urządzenia. Czy ustawiłeś role Relay dla odpowiednich GPIO i przypisałeś im kanały?

Czy widziałeś poradnik migawki?
https://www.elektroda.com/rtvforum/topic3972935.html

mbolty · Answer

Dzięki, już przeczytałem ten post. Edytowałem swój post i dodałem obraz konfiguracji oraz część dziennika.

p.kaczmarek2 · Answer

Widzę, że masz dwa przekaźniki, jeden na kanale 1, a drugi na kanale 2. Jeśli zmieniasz stany kanałów z panelu www, to czy przekaźniki klikają?

mbolty · Answer

już rozwiązałem.


//Configurar alias  Aliases
alias Set_Stop backlog setChannel 2 0; setChannel 1 0
alias Set_Open backlog setChannel 1 1
alias Set_Close backlog setChannel 2 1
alias Start_Opening backlog stopAllScripts; startScript autoexec.bat openBlind
alias Start_Closing backlog stopAllScripts; startScript autoexec.bat closeBlind
alias Stop_All backlog stopAllScripts; startScript autoexec.bat stopBlind

// Channel 60 segundos de trabajo
setChannel 60 15

//crear botones GUI  para el panel HTTP
startDriver httpButtons

setButtonEnabled 1 1
setButtonLabel 1 "Open"
setButtonCommand 1 Start_Opening

setButtonEnabled 3 1
setButtonLabel 3 "Close"
setButtonCommand 3 Start_Closing

setButtonEnabled 2 1
setButtonLabel 2 "Stop"
setButtonCommand 2 Stop_All
setButtonColor 2 red

// Ocultar los botones de los reles en la  GUI HTTP
setChannelVisible 1 0
setChannelVisible 2 0
setChannelVisible 3 0

// Cargar Event Handlers
addEventHandler OnHold 26 Start_Closing
addEventHandler OnHold 24 Start_Opening
addEventHandler OnClick 11 Stop_All

// Detener persiana al encender
goto stopBlind
return

// Script abrir
openBlind:
Set_Stop
delay_s 0.1
Set_Open
delay_s $CH60
Set_Stop
return

// Script cerrer
closeBlind:
Set_Stop
delay_s 0.1
Set_Close
delay_s $CH60
Set_Stop
return

// Script detener
stopBlind:
Set_Stop
return

Mam tylko jedno pytanie o wartości 60 dolarów. Wartość nie mogła zostać wysłana przez MQTT przez Home Assistant, aby móc ją zmodyfikować zgodnie z czasem każdego silnika?
Bardzo dziękuję
(prześlę zdjęcia gotowego projektu)

richardsg307 · Answer

W końcu odkryłem, że mogę nacisnąć przycisk Otwórz okno po raz drugi i otworzy się trochę (dużo) więcej. Aby go zamknąć, potrzebowałem więcej czasu, więc zmieniłem ten kod z powrotem na liczbę taką jak 25 (sekund), aby upewnić się, że jest zamknięty bez względu na to, jak daleko go otworzyłem. Siłownik ma odcięcie, gdy osiągnie pozycję zamkniętą lub gdy samo okno zostanie zamknięte (przed położeniem zamknięcia siłownika) i silnik utknie.

Promuję tematy:
19.04.2023 Programowanie sterownika rolet Skylight, skrypty OpenBeken, uwolnienie od Chińskiej chmury

p.kaczmarek2 · Answer

Bardzo dobra robota, Domyślnie kanały są wysyłane tylko wtedy, gdy są używane do podstawowych operacji we/wy, ale to zachowanie można zmienić. Podam Ci dwie metody: 1. Po prostu ręcznie opublikuj wartość kanału Kod: text Rozwiń Zaznacz wszystko Kopiuj do schowka addEventHandler OnChannelChange 30 publishInt myCustomValue $CH30  2. Możesz także zaktualizować OpenBeken do najnowszej wersji, a następnie upewnić się, że używasz kanału do 31, a następnie w aplikacji internetowej zmienić typ: Jeśli ustawisz typ, na przykład na „Niestandardowy”, Obk będzie wiedział, że coś jest na tym kanale i opublikuje to, gdy się zmieni. Pamiętaj, że możesz również łatwo ustawić dowolny kanał za pomocą MQTT.

mbolty · Answer

Witam, poprawiłem autoexec.bat i stworzyłem kilka czujników i automatyzacji w asystencie domowym.
Chciałbym poznać waszą opinię i czy jest możliwe ulepszenie tego, co stworzyłem.
Dziękuję wszystkim.


//Configurar alias  Aliases
alias Set_Stop backlog setChannel 2 0; setChannel 1 0
alias Set_Open backlog setChannel 1 1
alias Set_Close backlog setChannel 2 1
alias Start_Opening backlog stopAllScripts; startScript autoexec.bat openBlind
alias Start_Closing backlog stopAllScripts; startScript autoexec.bat closeBlind
alias Stop_All backlog stopAllScripts; startScript autoexec.bat stopBlind

// Channel 31 segundos de trabajo por defecto configurable por mqtt
setChannel 31 5
//crear botones GUI  para el panel HTTP
startDriver httpButtons

setButtonEnabled 1 1
setButtonLabel 1 "Open"
setButtonCommand 1 Start_Opening

setButtonEnabled 3 1
setButtonLabel 3 "Close"
setButtonCommand 3 Start_Closing

setButtonEnabled 2 1
setButtonLabel 2 "Stop"
setButtonCommand 2 Stop_All
setButtonColor 2 red

// Ocultar los botones de los reles en la  GUI HTTP
setChannelVisible 1 0
setChannelVisible 2 0
setChannelVisible 3 0
setChannelVisible 31 1
setChannelVisible 32 0
setChannelVisible 60 0

// Cargar Event Handlers
addEventHandler OnClick 26 Start_Closing
addEventHandler OnClick 24 Start_Opening
addEventHandler OnClick 10 Stop_All

// Detener persiana al encender
goto stopBlind
return

openBlind:
Set_Stop
delay_s 0.1
Set_Open
publish state_topic opening
delay_s $CH31
Set_Stop
publish state_topic open
return

closeBlind:
Set_Stop
delay_s 0.1
Set_Close
publish state_topic closing
delay_s $CH31
publish state_topic close
Set_Stop
return

stopBlind:
Set_Stop
publish state_topic stopped
return


sensor:
    - name: "estado persiana"
      state_topic: "obk_02/state_topic/get"
    - name: "tiempo persiana"
      state_topic: "obk_02/31/get"


alias: timeblindha_2device
description: send work time to device from home assistant
trigger:
  - platform: state
    entity_id:
      - input_button.set_tiem_blind
condition: []
action:
  - service: mqtt.publish
    data:
      qos: 0
      retain: false
      topic: obk_02/31/set
      payload_template: "{{ states('input_number.timepersiana')|float }}"
mode: single


alias: timeblind_device2ha
description: synchronize device working time with home assistant
trigger:
  - platform: mqtt
    topic: obk_02/31/get
condition: []
action:
  - service: input_number.set_value
    data:
      value: "{{ states('sensor.tiempo_persiana')|float }}"
    target:
      entity_id: input_number.timepersiana
mode: single

Utwórz przycisk "input_button.set_tiem_blind", aby nowy czas pracy był wysyłany tylko po kliknięciu przycisku, a nie po zmianie wartości "input_number.set_value".
Czekam na dostarczenie przekaźników, aby dodać je do modułów.

balucio · Answer

>>20545714 >>20556900

Mam przełącznik wifi z trzema wyjściami, które kontrolują pojedynczą kolorową diodę LED. Dzięki poprzedniemu postowi znalazłem rozwiązanie, aby zablokować wyjścia i losowo zmieniać kolor diody co 60 sekund....

To jest główna część mojego pliku startup.bat

// Handle colors

alias Violet backlog cancelRepeatingEvent 30; setChannel 1 1 
alias Blue backlog cancelRepeatingEvent 30; setChannel 2 1
alias Green backlog cancelRepeatingEvent 30; setChannel 3 1

alias Random backlog cancelRepeatingEvent 30; setChannel 60 $rand01*3 1; setChannel $CH60 1;addRepeatingEventID 60 -1 30 Random

alias onViolet backlog setChannel 2 0; setChannel 3 0; setChannel 60 1
alias onBlue backlog setChannel 1 0; setChannel 3 0; setChannel 60 2
alias onGreen backlog setChannel 1 0; setChannel 2 0; setChannel 60 3

alias changeColor backlog setChannel 1 0; setChannel 2 0; setChannel 60 3


// interlook events
addChangeHandler Channel1 == 1 onViolet
addChangeHandler Channel2 == 1 onBlue
addChangeHandler Channel3 == 1 onGreen

// Gui buttons
startDriver HTTPButtons

// Random
setButtonEnabled 10 1
setButtonLabel 10 "Random"
setButtonCommand 10 Random
setButtonColor 10 gray

setButtonEnabled 11 1
setButtonLabel 11 "Blue"
setButtonCommand 11 Blue
setButtonColor 11 blue

setButtonEnabled 12 1
setButtonLabel 12 "Violet"
setButtonCommand 12 Violet
setButtonColor 12 BlueViolet

setButtonEnabled 13 1
setButtonLabel 13 "Green"
setButtonCommand 13 Green
setButtonColor 13 green

// Hide the default GUI buttons
setChannelVisible 1 0
setChannelVisible 2 0
setChannelVisible 3 0

// Start color
Random

OpenBeken Konfigurowanie przycisków Otwórz/Zatrzymaj/Zamknij na przełączniku Sma

Post #1

Post #2

Post #3

Post #4

Post #5

Post #6

Post #7

Post #8

Post #9

Post #10

Post #11

Post #12

Post #13

Post #14

Post #15

Post #16

Post #17

Post #18

Podsumowanie tematu