Zarządzanie przyciskami oraz skrypt do modułu CB3S w przełączniku LoraTap SC400W-EU

clearIO
// ====== CONFIG ======
// Used to hold the delay value in millis for sleeping during closing or opening loop
// Play with your curtain and find the right value for this delay

SetChannel 8 100

// Delay to wait (millis) before starting to move the curtain after we close both relays
// maybe it is not necessary, but I prefer it to be to ensure we do not have
// both open and close relays powered simultaneously:
SetChannel 7 500

// MQTT stuff
MqttClient lr_curtain_2
MqttHost <YOUR_HA_MQTT_HOST>
MqttUser <YOUR_HA_MQTT_USER>
MqttPassword <YOUR_HA_MQTT_PASSWORD>

// ====== END OF CONFIG ======

// set channels 7, 8 and 9 to be private, so that we do not spend resources to publish their values:
SetChannelPrivate 7 1
SetChannelPrivate 8 1
SetChannelPrivate 9 1

// HIde relays from GUI
setChannelVisible 1 0
setChannelVisible 3 0

// We start the main opening/closing loop with a delay
// and than immediately have a calibration delay
// so, let's decrement the calibration delay to not have them both
// at the beginning of the loop:

addChannel 7 -$CH8 0 5000

PowerSave 1
//startDriver ntp

// set pins and channels

// Pin 7 is connected to opening relay
SetPinRole 7 Rel
// we also connect it to channel 1
SetPinChannel 7 1
SetChannelLabel 1 "Up"

// Pin 6 is connected to closing relay
SetPinRole 6 Rel
// we also connect it to channel 3
SetPinChannel 6 3
SetChannelLabel 3 "Down"
// crea los botones
setChannelType 20 Toggle
SetChannelLabel 20 "Down"
setChannelType 21 Toggle
SetChannelLabel 21 "Stop"
SetChannel 21 1
setChannelType 22 Toggle
SetChannelLabel 22 "Up"
// 23 - stop button 
SetPinRole 26 Btn
// 24 - opening button
SetPinRole 9 Btn
// 26 - closing button
SetPinRole 24 Btn

// CH9 - saved position for reboot
// CH10 - current position
// CH11 - target position

SetChannelLabel 9 "Saved Position"
setChannelType 9 Dimmer
SetChannelLabel 10 "Current Position"
setChannelType 10 Dimmer
SetChannelLabel 11 "Target Position"
setChannelType 11 Dimmer

SetStartValue 9 -1

// read position saved before reboot:
SetChannel 10 $CH9
SetChannel 11 $CH9

// Setup LED:
//SetPinRole 10 LED
//SetPinChannel 10 4

// ============= MQTT ============

// Let it shine when MQTT connection is established:
addEventHandler MQTTState 1 SetChannel 4 1
addEventHandler MQTTState 0 SetChannel 4 0

// [2] Always set MQTT Retain flag to all published values;
// [7] Broadcast self state every N seconds:
// [10] Broadcast self state on MQTT connect
flags 1156

// Inform HA about our values every 30 seconds, publish 2 values per second
mqtt_broadcastInterval 30
mqtt_broadcastItemsPerSec 2

alias Set_Stop backlog setChannel 3 0; setChannel 1 0
alias Start_Opening backlog SetChannel 22 1; stopAllScripts; startScript autoexec.bat openSkylight
alias Start_Closing backlog SetChannel 20 1; stopAllScripts; startScript autoexec.bat closeSkylight
alias Stop_All backlog stopAllScripts; startScript autoexec.bat stopSkylight
alias Open_To_Target backlog stopAllScripts; startScript autoexec.bat openSkylightToTarget

alias Stop_Clicked backlog Set_Stop; Stop_All; SetChannel 21 1

// Click and fast release will effect in fully closing or opening.
// If during this process we click on the same button again, it stops 
// EDIT PINS..............................................................................................................................................
addEventHandler OnClick 24 if $CH03==1 then Stop_Clicked else Start_Closing
addChangeHandler Channel20 == 1 if $CH03==1 then Stop_Clicked else Start_Closing
addEventHandler OnClick 9 if $CH01==1 then Stop_Clicked else Start_Opening
addChangeHandler Channel22 == 1 if $CH01==1 then Stop_Clicked else Start_Opening
addEventHandler OnClick 26 Stop_Clicked
addChangeHandler Channel21 == 1 if $CH02==1 then Stop_Clicked else Stop_Clicked
//..............................................................................................................................................................................

addChangeHandler Channel20 == 1 backlog SetChannel 21 0; SetChannel 22 0
addChangeHandler Channel21 == 1 backlog SetChannel 20 0; SetChannel 22 0
addChangeHandler Channel22 == 1 backlog SetChannel 20 0; SetChannel 21 0
return

// === OPEN TO GIVEN PERCENTAGE ===
openSkylightToTarget:
   Set_Stop
   delay_ms $CH7
openSkylightToTarget_again:
   delay_ms $CH8
        if $CH10<$CH11 then goto continue_opening
        if $CH10>$CH11 then goto continue_closing

   // we are done, we reached our target
   // If we were opening or closing fully, we let the motor
   // run for 3 seconds for the case we are uncalibrated:
   if $CH10==0 then goto calibrate
   if $CH10==100 then goto calibrate
   goto openSkylightFinished
continue_opening:
        // Unset_Close
   setChannel 3 0
        // Set_Open
   setChannel 1 1
   // increment:
        addChannel 10 1 0 100
   goto openSkylightToTarget_again

continue_closing:
        // Unset_Open
   setChannel 1 0
        // Set_Close
   setChannel 3 1
   // decrement:
        addChannel 10 -1 0 100
   goto openSkylightToTarget_again

calibrate:
   delay_ms 3000
   Set_Stop
   SetChannel 9 $CH10
   return
openSkylightFinished:
   Set_Stop
   SetChannel 9 $CH10
   return

// === CLOSE ===
closeSkylight:
   SetChannel 11 0
   goto openSkylightToTarget
return

// === OPEN ===
openSkylight:
   SetChannel 11 100
   goto openSkylightToTarget
return

// === STOP ===
stopSkylight:
   Set_Stop
   SetChannel 11 $CH10
   SetChannel 9 $CH10
return